Note

This Mathematica notebook is from the WWW project A Visual Dictionary of Special Plane Curves. Copyright © 1995-2000 by Xah Lee. (http://xahlee.org/)

Packages and Initializations

Needs["ParaPlot`"]
Needs["PlaneCurveFormulas`"]
Needs["PlaneCurveGenerator`"]

Needs["Graphics`ImplicitPlot`"]
(*MathSource Item:0200-529*)

Semicubic Parabola

Semicubic Parabola can be defined as the Evolute of Parabola.(See Evolute)

Parametric formula: {t^3, t^2}. -Infinity < t < Infinity
Cartesian equation: x^2 == y^3.
Polar Equation: r == Tan[t]^2 Sec[t]

{t^3, t^2} is the evolute of the parabola {(-4 t)/9, -8/27 + t^2/3}.

ParaPlot[ Parabola[][t], {t, -10, 10, .25},
	PlotEvolute->True,
	PlotDot->False, PlotRange->{{-1,1} 15, {-.5,15}},
	AspectRatio->Automatic
];

ParaPlot[ 
	{ Parabola[][t], Evolute[ Parabola[][t], t] },
	{t, -10, 10},
	PlotStyle->{Hue[.65], Hue[.0]},
	PlotRange->{{-1,1} 15, {-.5,15}},
	AspectRatio->Automatic
];

The parabola {(-4 t)/9, -8/27 +t^2/3} is the parabola {t,1/4 t^2} scaled by a factor of 4/27 and translated by {0, -8/27}. (see Parabola)

Semicubic parabola inherets the property from parabola that when streched horizontally or vertically, the curve remain unchanged.
The semicubic parabola
	{t^3, t^2}{a,b}          is equivalent to 
	{t^3, t^2}*(b^3/a^2).

Clear[a,b];

{a,b} = {2,4};

ParaPlot[ { {t^3,t^2} {a,b}, {t^3,t^2} b^3/a^2 },
	{t, -5, 5},
	PlotStyle->{{Hue[.5],Thickness[.007]},
		{Hue[0],Thickness[.007], Dashing[{.05,.05}]}
	},
	PlotRange->{{-1,1}3,{-0.1,3}} 3,
	AspectRatio->Automatic
];

Clear[a,b];

The Pedal of a semicubic parabola with respect to the focus of a parabola the semicubic parabola is derived from is another parabola.

Pedal[ Evolute[ Parabola[][t], t ], t, {0,1}]

Clear[curve, curve2];

curve = First@ ParametricPlot[ 
	Evaluate@ Parabola[][t],
	{t, -8, 8},
	PlotStyle->{{Hue[.9,.5,1],Thickness[.007]}},
	AspectRatio->Automatic,
	DisplayFunction->Identity

];

curve2 = First@ ParaPlot[ 
	Evolute[Parabola[][t],t],
	{t, -7, 7, .25},
	PedalPoint->{0,1},
	PlotDot->False,
	CurveColorFunction->{Hue[.65,.2,1]&},
	CurveStyle->{Thickness[.007]},
	PlotRange->{{-1,1} 3 ,{.5,6}},
	AspectRatio->Automatic,
	DisplayFunction->Identity
];

Show[
	Graphics[{
		curve, curve2
	}], AspectRatio->Automatic,
	Axes->True,
	PlotRange->{{-1,1}8,{-1,13}},
	Background->GrayLevel[0]
];

ParaPlot[
	{
		Evolute[ Parabola[][t], t ],
		Pedal[ Evolute[ Parabola[][t], t ], t, {0,1}]
	},
	{t, -13, 13},
	PlotRange->{{-1,1} 3 ,{.5,6}},
	PlotStyle->{{Hue[.67]},{Hue[0]}},
	AspectRatio->Automatic
];

Graphics Gallery

ParaPlot[ 
	SemicubicParabola[][t],
	{t, -10,10, .2},
	PedalPoint->{0,-15},
	PlotDot->False,
	CurveColorFunction->{Hue[.65]&},
	CurveStyle->{Thickness[.007]},
	PlotRange->{{-1,1},{-1,1}}20,
	AspectRatio->Automatic,
	Background->Hue[0,0,0]
];

ParametricPlot[ 
	Evaluate@ Parallel[
		Pedal[ SemicubicParabola[][t], t, {0,-20}],
		t,
		Range[-4,30,2]
	],
	{t, -10,10},
	PlotRange->{{-1,1},{-1,1}}30,
	AspectRatio->Automatic,
	Axes->False,
	Epilog->First@
		ParametricPlot[ Evaluate@ SemicubicParabola[][t],{t,-10,10},
			DisplayFunction->Identity
		]
];

ParaPlot[{(-4 t)/9, -8/27 + t^2/3}, {t, -10, 10, .25},
	NormalLineLength->100,
	PlotDot->False,
	CurveColorFunction->{Hue[.75,.8,1]&},
	PlotRange->{{-1,1},{-1,1}}20,
	AspectRatio->Automatic,
	Axes->None
];