Note

This Mathematica notebook is from the WWW project A Visual Dictionary of Special Plane Curves. Copyright © 1995-2004 by Xah Lee. (http://xahlee.org/)

Packages and Initializations

Needs["ParaPlot`"]
(*MathSource Item:0207-986*)
Needs["PlaneCurveFormulas`"]
Needs["PlaneCurveGenerator`"]

Needs["Graphics`ImplicitPlot`"]
(*MathSource Item:0200-529*)

Quadratrix of Hippias

Description

Off[ParametricPlot::"pptr"]
ParametricPlot[Evaluate[QuadratrixOfHippias[][t]], 
        Evaluate[Prepend[Range[-5 π, 5 π, π], t]], 
        PlotStyle -> {{Hue[0.7], Thickness[0.003]}}, 
        PlotRange -> {{-1, 1} 5*π, {-1, 1} 10}, 
        AspectRatio -> Automatic, 
        Ticks -> (({#, #} &)@
              Table[{x*Pi, ToString[x]~StringJoin~"π"}, {x, -5, 
                  5}])];
On[ParametricPlot::"pptr"]

Quadratrix (or trisectrix) of Hippias is the first named curve other than circle and line. It is conceived by Hippias of Ellis (ca 460 BC) to trisect the angle. (see Three Famous Problems of antiquity) The curve is better known as quadratrix because it can also be used to square the circle.

Mechanical Construction:
(1) Let there be a square in the first quardrant with lower-left coner at the origin.
(2) Let there be a line parallel to the x-axis and gradually moving up at a constant speed from the bottom side of the square until it reaches the upper side of the square.
(3) Let there be an angle in standard position. The angle increase at a constant speed from 0 to Pi/2. Both the angle and line movement start and finish in simultanesouly.
(4) The intersections of the line and the angle is quadratrix of Hippias.

QuadratrixOfHippiasGenerator[{.01,1.2}, LastFrameOnly->True];

Given the definition, it is easy to derive the parametric equation. Let the parameter t be the angle, 0 < t < Pi/2 and the square having side length Pi/2. So immediately, y = t. Since we know the angle and one side of the triangle y at any time t, using the identity Cot[t] = x/y, we find the parametric equation to be

	y = t,
	x = t Cot[t].

and the Cartesian equation is x == y Cot[y].

ImplicitPlot[ x == y Cot[y],
	{x,-5,5},{y,-5,5},
	AspectRatio->Automatic
];

Other formulas:
Parametric formula: {t, t Cot[t]}. -2 Pi <= t <= 2 Pi
Parametric Polar formula: {t/Sin[t], t}
Polar Equation: r == theta/Sin[theta]

Trisect the angle

The curve can be used to trisect any acute angle.
To trisect angel AOB, one first find distance OE, take one third of distance OE to get OD (trisection of a segment can be done with ruler and compass). Let the intersection of the curve and the horizontal line at D be P, then the angle AOP is one third of angle AOB. This follows because by the definition of the curve, 
distance[O,E]/distance[O,C] == angle[A,O,B]/(Pi/2).
If distance[O,C] == Pi/2, then distance[O,E] == angle[A,O,B].

Clear[gp,p]

Show[
	Graphics[	
	{
		First@ ParametricPlot[
			Evaluate[{t Cot[t], t}],
			{t,0.001, 1.57},
			PlotStyle->{Hue[.65]},
			DisplayFunction->Identity
		],
		{	Line[{{0,0},{Pi/2,0},{Pi/2,Pi/2},{0,Pi/2},{0,0}}],
			Circle[{0,0}, Pi/2, {0,Pi/2}],
			Hue[0], Thickness[.007],
			Line[{{0,0}, Pi/2 {Cos[.9],Sin[.9]}}],
			Hue[0.35,1,.5],
			Line[{{0, .9},{Pi/2, .9}}],
			Hue[0], Thickness[.004],
			Line[{{0,0}, Pi/2 {Cos[.3],Sin[.3]}}],
			Line[{{0,0}, Pi/2 {Cos[.6],Sin[.6]}}],
			Hue[0.35,1,.5],
			Line[{{0, .3},{Pi/2, .3}}],
			Line[{{0, .6},{Pi/2, .6}}]
		},
		{	Hue[.65], PointSize[.02],
			Point /@ {{0,Pi/2},{0,0},{Pi/2,0},{.9 Cot[.9], .9},
				{.3 Cot[.3], .3}
			},
			Text["A", {Pi/2, 0}, {-2, 2}],
			Text["O", {0, 0}, {-2, 2}], 
			Text["C", {0, Pi/2}, {-2, 2}],
			Text["P", {.3 Cot[.3],.3}, {-1,-2}],
			Text["B", {.9 Cot[.9],.9}, {0,-2}],
			Text["D", {0,0.3}, {1.5,0}],
			Text["E", {0,.9}, {1.5,0}]
		}
	}
	
	],
	AspectRatio->Automatic, Axes->True,
	PlotRange->All,
	Ticks->None
];